ot4xb.examples (readonly)

Retrieving the computer name from the NETBIOS

pbn_NOSPAM_@pablob.com — Fri, 13 Jun 2008 11:11:23 +0200

#include "ot4xb.ch"
// ---------------------------------------------------------------------------
function Main()
? cPrintf( "Computer Name : [%s]", cGetComputerName() )
inkey(0)
return NIL
// ---------------------------------------------------------------------------
function cGetComputerName()
local cn := ChrR(0,256)
local cb := 255
@kernel32:GetComputerNameA(@cn,@cb)
return TrimZ(cn)
// ---------------------------------------------------------------------------

Retrieving a list of services with the status Active

pbn_NOSPAM_@pablob.com — Sun, 13 Jul 2008 17:41:12 +0200

function aGetActiveServices()
local hSc :=  @advapi32:OpenSCManagerA(0,0,SC_MANAGER_ENUMERATE_SERVICE)
local lResult
local pData,cbData
local nRH      := 0  // Resume Handle
local cbNeeded := 0
local nSvcCnt  := 0
local lLoop    := .T.
local aSvc     := {}
local n,ns

if( hSc == 0 ) ; return {} ; end

cbData := 0x10000 ; pData  := _xgrab(cbData)

while lLoop
   nSvcCnt  := 0
   lResult := ( @advapi32:EnumServicesStatusExA( hSc,SC_ENUM_PROCESS_INFO,;
                nOr(SERVICE_DRIVER,SERVICE_WIN32),SERVICE_ACTIVE,pData,cbData,;
                @cbNeeded,@nSvcCnt,@nRH,0) != 0 )
                
   lLoop := (nFpGetLastError() == ERROR_MORE_DATA)
   if( lResult .or. lLoop )
      ns := 0
      for n := 1 to nSvcCnt
         aadd( aSvc , PeekDWord(pData,@ns, 11) )
         aSvc[-1][1] := PeekStr(aSvc[-1][1],,-1)
         aSvc[-1][2] := PeekStr(aSvc[-1][2],,-1)
      next
   end
   if lLoop .and. ( cbNeeded > cbData )
       _xfree( pData ); cbData := cbNeeded ; pData  := _xgrab(cbData)
   end
end
_xfree( pData )
@advapi32:CloseServiceHandle(hSc)
return aSvc

Generating random strings ( ot4xb build 1.5.2.79)

pb_no_spam_@_remove_all_betwen_underscores_xbwin.com — Fri, 12 Sep 2008 22:52:31 +0200

Minimum ot4xb build 1.5.2.79
cGenRndStr() is introduced in ot4xb build 1.5.2.54 but was produced about 10% of duplicates
was fixed in 1.5.2.79
----------------------------------------------------------------------
I've run the test in my computer ( Intel Core Duo 3Ghz, 2Gb RAM)
with the following results
Elapsed Time: 3 Seconds
1000000 Items 0 Duplicates
----------------------------------------------------------------------

#include "ot4xb.ch"
#define MAX_LOOP  1000000
// ---------------------------------------------------------------------------
function Main()
local nSeconds := Seconds()
local pHt      := _HDICT_NEW(,MAX_LOOP)
local n
for n := 1 to MAX_LOOP
   _HDICT_SETPROP(pHt,cBin2Hex(cGenRndStr(8,.T.)), 0) 
   // cBin2Hex() is needed here as the hash table is case insensitive
next
? cPrintf(" Elapsed Time: %i Seconds",Seconds() - nSeconds)
? cPrintf(" %i Items  %i Duplicates",MAX_LOOP , MAX_LOOP - _HDICT_COUNT(pHt) )
inkey(0)
return NIL
// ---------------------------------------------------------------------------

Retrieving Drive Information

pb_no_spam_@_remove_all_betwen_underscores_xbwin.com — Fri, 26 Sep 2008 21:45:24 +0200

function ShowDriveInfo(cRoot , cStr )
local oInfo  := GetDriveInfo(cRoot)

cStr += CRLF + PadC( "| " + cRoot + " |",78,"-")
if oInfo == NIL
   cStr += CRLF + "Error: Unable to retrieve the volume information."
   cStr += CRLF + cPrintf( "Type of Drive:[%s]",_n2dt_(nGetDriveType(cRoot)) )
else
   cStr += CRLF + cPrintf( "Label: [%s] Serial:[%lX]" ,  oInfo:cLabel , oInfo:nSerial )
   cStr += CRLF + cPrintf( "MaxFileNameLen:[%i] FileSystem:[%s] Type:[%s]",;
                  oInfo:nMaxCompLen,oInfo:cFileSystem,_n2dt_(oInfo:nDriveType) )
end
return cStr

Forced Administrative Privileges

pb_no_spam_@_remove_all_betwen_underscores_xbwin.com — Tue, 30 Sep 2008 21:25:27 +0200

This sample will check first if the current user have administrative privileges

if lIsUserAdmin()
   ? "Current user has administrative privileges"

If no sufficient privileges will show you a screen to get a user/pwd with admin privileges
will try to run the same exe with the provided user/pwd account
and close itself if succesfull

So you will get a new instance of the same exe but this time running with the privileges of the provided account.

function lLogonAsAdmin()    
local cUser      := Space(60)
local cPwd       := Space(60)
local aSI        := AFill(Array(17),0)
local aPI        := AFill(Array(4),0)
local cWApp      := cSzAnsi2Wide(AppName(.F.)) 
local result     := .F.
aSI[1] := 68       
if !lLogOnDialog(@cUser,@cPwd) ; return .F. ; end 

cUser := cSzAnsi2Wide(cUser)
cPwd  := cSzAnsi2Wide(cPwd)

result := ( @AdvApi32:CreateProcessWithLogonW(cUser,cSzAnsi2Wide("."),cPwd,1,cWApp,0,0,0,0,aSI,@aPI) != 0 )
if result 
   if aPI[1] != 0 ; @kernel32:CloseHandle(aPI[1]) ; end
   if aPI[2] != 0 ; @kernel32:CloseHandle(aPI[2]) ; end     
end
return result

Taskbar Icon

pb_no_spam_@_remove_all_betwen_underscores_xbwin.com — Wed, 8 Oct 2008 13:40:24 +0200

#include "ot4xb.ch"
// ---------------------------------------------------------------------------
#define IDI_APPLICATION     32512
#define IDI_HAND            32513
#define IDI_QUESTION        32514
#define IDI_EXCLAMATION     32515
#define IDI_ASTERISK        32516
#define IDI_WINLOGO         32517
// ---------------------------------------------------------------------------
#define NIIF_NONE       0x00000000
#define NIIF_INFO       0x00000001
#define NIIF_WARNING    0x00000002
#define NIIF_ERROR      0x00000003
// ---------------------------------------------------------------------------
proc dbesys ; return
// ---------------------------------------------------------------------------
proc main()
local nKey := 0
local oTbi := TNotifyIcon():New(0,IDI_EXCLAMATION, "Using a system icon")
local oCrt := SetAppWindow()

oTbi:bOnContextMenu  := {|| QOut("OnContextMenu")}
oTbi:bOnLDblClick    := {|| QOut("OnLDblClick  ")}
oTbi:bOnLClick       := {|| QOut("OnLClick     ")}
oTbi:bOnMouseMove    := {|| QOut("OnMouseMove  ")}


? "Press a key to show icon from system in the taskbar ... " ; Inkey(0)
oTbi:Show()
oTbi:ShowInfo(,"From System",1)

? "Press a key to show icon from file in the taskbar ... " ; Inkey(0)
oTbi:Modify("0.ico",NIL,"Using a Icon From File")
oTbi:ShowInfo(,"From File",2)

? "Press a key to show icon from EXE resource in the taskbar ... " ; Inkey(0)
oTbi:Modify(NIL,2,"Using a Icon From Resource in EXE")
oTbi:ShowInfo(,"From resource in EXE",3)

? "Press a key to show icon from DLL resource in the taskbar ... " ; Inkey(0)
oTbi:Modify("test.dll",3,"Using a Icon From resource in DLL")
if oTbi:ShowInfo(,"From resource in DLL",1)
   ? "Press a key to hide the ballon ... " ; inkey(0)
   oTbi:HideInfo()
end
? "Press a key to start the icon animation" ; Inkey(0)
oTbi:StartAnimation({{,1,""},{,2},{,3},{,4},{,5},{,6},{,7},{,8},{,9},{,10}}, 200 )

? "Press a key to stop the icon animation" ; Inkey(0)
oTbi:StopAnimation()

? "Press ESC to close ... " ; while (nKey := Inkey(0)) != 27 ; end
oTbi:Destroy()
return